运行vba代码后，execl的功能都被限制，如何解决？

宏猫大哥 • 2021年4月6日下午4:07 • 办公

由于想把xecl表格的某些功能限制，自己鼓捣了一段vba代码，用代码的形式一劳永逸的规范好填写内容格式，结果运行Vba代码后，导致execl的此项功能都不能用了。

尝试把代码删除，不行；把文件删除，也不行；最后干脆把execl重装还是不行。最后搜索了大量的资料，终于找到了一项解决办法。

所有程序自动运行,都会在Excel的XLSTART文件夹内，所以把这个文件夹内的东东清除掉就可以了。我用的清理XLSTART文件夹工具，遇到的问题轻松解决了，分享给大家参考。

工具bat文件代码(来自网络)：

这个清理XLSTART文件夹工具主要用于清理Office 2003/2007/2010版本的Excel的XLSTART文件夹内的所有文件，请谨慎使用，使用前请安全关闭所有Excel工作簿并及时保存未存档的工作，为保证清理效果，本批处理会强制关闭所有Excel程序。

双击bat后出现Microsoft Office Excel Recovery complete:-)则表明修复完成。

REM
REM COPYRIGHT : Copyright (c) 2013 WangYe. All rights reserved.
REM
REM DESCRIPTION : Clear ALL FILES in Excel XLSTART directory.
REM AUTHOR : WANGYE
REM WEBSITE : http://wangye.org
REM
REM Compatible with Office 2003/2007/2010
REM
REM Last Update : 2013/1/10
REM
@ECHO OFF

:BEGIN
CLS
ECHO Copyright (c) 2013 WangYe. All rights reserved.
ECHO For more information please visit http://wangye.org
ECHO.
ECHO Please wait...

TASKKILL /F /IM EXCEL.EXE>NUL 1>NUL 2>NUL

SETLOCAL EnableDelayedExpansion

FOR /L %%i IN (14,-1,11) DO (
if %%i NEQ 13 (
SET KEY_NAME="HKLM\SOFTWARE\Microsoft\office\%%i.0\Excel\InstallRoot"
FOR /F "tokens=2*" %%A IN ('REG QUERY !KEY_NAME! /v "Path" 2^>NUL ^| FINDSTR "REG_SZ"') DO (
SET ExcelInstallDir=%%B
CALL :EMPTY_DIR "!ExcelInstallDir!\XLSTART">NUL
)
)
)

SET EXCELDIR=\Microsoft\Excel
CALL :EMPTY_DIR "%APPDATA%%EXCELDIR%\XLSTART">NUL
DEL /F /S /A /Q "%APPDATA%%EXCELDIR%">NUL 1>NUL 2>NUL

GOTO :SUCCEEDED

:EMPTY_DIR
ECHO %1
IF EXIST %1 (
DEL /F /S /A /Q %1>NUL 1>NUL 2>NUL
RMDIR /S /Q %1>NUL 1>NUL 2>NUL
)
MKDIR %1>NUL 1>NUL 2>NUL
GOTO :EOF

:SUCCEEDED
ECHO.
ECHO Microsoft Office Excel Recovery complete:-)
ECHO.
PAUSE

:EOF
EXIT

[原创文章]，作者：宏猫大哥，如若转载，请自觉注明出处：http://www.vbamall.com/296.html

亲们，如果喜欢本站，请在PC端点击 [支持宏猫网]，不花一分钱即可捐赠支持到我们，谢谢！